***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Mar 26, 2021                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt PZ1AL5V6B-AU A K 
.param
+vc0 = 8.846e-10		vc1 = 1.686e-10		vc2 = 0.500			vc3 = 6.003e-11		vc4 = 2.843
+tc1 = 1.551e-2		tc2 = 1.261e-2		tc3 = 6.351e-3		tc4 = 3.821e-3
.func irexp(v) {(vc0+vc1*v**vc2)*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+(vc3*exp(vc4*v))*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
d1 A K zener
g1 K A value = {irexp(v(K,A))}
.model zener d
***** flag parameter *****
+level = 1
***** dc model parameter *****
+ is = 3.595e-15		   n = 9.978e-1		       rs = 2.288e-3
+ibv = 1.0e-1			 nbv = 0.8			  bv = 5.6
+ikf = 5.029e-1
***** capacitance parameter *****
+cjo = 9.100e-10		   m = 2.342e-1		  vj = 3.905e-1
+ fc = 0.5
***** temperature coefficient *****
+tnom = 25			  eg = 1.100		 xti = 3
+trs1 = 6.856e-4		trs2 = 7.203e-6		tikf = 5.0e-3
+tbv1 = 3.277e-4		tbv2 = 7.121e-8	
.ends PZ1AL5V6B-AU
*$
